Notes

Disk info for DOS_Tool_Kit_v1.0_1980_Apple.do:

File Name: a2_DOS_Tool_Kit_v1.0_1980_Apple/DOS_Tool_Kit_v1.0_1980_Apple.do
Disk Name: DISK VOLUME #254
Physical Size (bytes): 143360
Free Space (bytes): 768
Used Space (bytes): 142592
Physical Size (KB): 140
Free Space (KB): 0
Used Space (KB): 139
Archive Order: DOS
Disk Format: DOS 3.3
Total Sectors: 560
Free Sectors: 3
Used Sectors: 557
Tracks On Disk: 35
Sectors On Disk: 16

Disk directory for DOS_Tool_Kit_v1.0_1980_Apple.do:

a2_DOS_Tool_Kit_v1.0_1980_Apple/DOS_Tool_Kit_v1.0_1980_Apple.do DISK VOLUME #254
* A 002 HELLO
* A 003 EDASM
* I 003 INTEDASM
* B 008 EDASM.OBJ
* B 036 ASSM
* B 016 EDITOR
B 002 ASMIDSTAMP
* B 005 RLOAD
* B 003 RBOOT
* R 019 APA
* A 003 LOADAPA
* R 012 HRCG
* A 004 LOADHRCG
* A 026 ANIMATRIX
* A 010 MAXWELL
* B 005 MAX.SET
* B 034 APPLE LOGO.PIC
* A 025 RIBBIT
* B 005 FROGS1.SET
* B 005 FROGS2.SET
* B 034 LILY PAD.PIC
* A 011 SKYLAB
* B 005 SKY1.SET
* B 005 SKY2.SET
* B 005 SKY3.SET
* B 005 MUSH.SET
* B 034 WORLD MAP.PIC
* B 005 ASCII.SET
* B 005 BLIPPO BLACK.SET
* B 005 BYTE.SET
* B 005 COLOSSAL.SET
* B 005 COUNT.SET
* B 005 CYRILLIC.SET
* B 005 ESPERANTO.SET
* B 005 FLOW.SET
* B 005 GOTHIC.SET
* B 005 GRAPHIC.SET
* B 005 GREEK.SET
* B 005 KATAKANA.SET
* B 005 MIRROR.SET
* B 005 OUTLINE.SET
* B 005 PINOCCHIO.SET
* B 005 PUDGY.SET
* B 005 ROMAN.SET
* B 005 SHADOW.SET
* B 005 SLANT.SET
* B 005 STOP.SET
* B 005 UPSIDE DOWN.SET
* B 030 BACK IT UP II+
T 022 ASIF.GAMES
T 011 ASIF.NON-GAMES
DOS 3.3 format; 768 bytes free; 142,592 bytes used.

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/ANIMATRIX.bas:

5 LOMEM: 24576
7 HGR : TEXT
10 ONERR GOTO 3000
20 GOSUB 1390
30 GOSUB 850
40 GOSUB 900
50 GOSUB 2100
290 REM READ KEYBOARD
300 C = PEEK(KB) -128: IF C <0 THEN 490
310 POKE KS,0
320 IF C = 1 THEN GOSUB 1070
330 IF C = 4 THEN 1660
340 IF C = 8 THEN GOSUB 1120
350 IF C = 9 THEN 1610
360 IF C = 11 THEN C = 91
365 IF C = 12 THEN C = 92
370 IF C = 13 THEN GOSUB 1200
375 IF C = 15 THEN C = 95
390 IF C = 19 THEN GOSUB 1240
400 IF C = 20 THEN GOSUB 630
410 IF C = 21 THEN GOSUB 1160
430 IF C = 26 THEN GOSUB 1090
440 IF C = 27 THEN 750
450 IF C <32 THEN 490
460 REM ACCEPT CHARACTER
470 IF SH AND C >63 AND C <96 THEN C = C +32
480 GOSUB 1030
490 REM READ PADDLES
500 P0 = PDL(0) *XP: IF ABS(P0 -PX -.5) >.7 THEN PX = INT(P0):PL = -1
510 P1 = (255 - PDL(1)) *YP: IF ABS(P1 -PY -.5) >.7 THEN PY = INT(P1):PL = -1
520 P0 = PX *4 +2 * INT(PX/7) +2:P1 = PY *4 + INT(PY/8) +1
530 XDRAW 2 AT P0,P1: FOR I = 1 TO 50: NEXT : XDRAW 2 AT P0,P1
540 IF PEEK(S0) >127 AND PL < >0 THEN PL = 0: GOSUB 570
550 IF PEEK(S1) >127 AND PL < >1 THEN PL = 1: GOSUB 570
560 GOTO 290
570 REM SET LOW BITS
580 X0 = INT(PX/7):Y0 = INT(PY/8):C = CM(X0,Y0):P0 = PX -X0 *7:P1 = PY -Y0 *8
590 C0 = CS +C *8 -256 +P1:I = PEEK(C0):J = 2 ^P0
600 X0 = INT(I/J):Y0 = I/J -X0:I = ( INT(X0/2) *2 +PL +Y0) *J: POKE C0,I
610 HCOLOR= 3 *PL: FOR X0 = 0 TO 6: FOR Y0 = 0 TO 4: IF C = CM(X0,Y0) THEN DRAW 1 AT X0 *30 +P0 *4 +2,Y0 *33 +P1 *4 +1
620 NEXT : NEXT : VTAB 14: HTAB 33: PRINT CG$: RETURN
630 REM TOGGLE HIGH BIT
640 X0 = INT(PX/7):Y0 = INT(PY/8):C = CM(X0,Y0):J = PY -Y0 *8
650 C0 = CS +C *8 -256 +J:I = PEEK(C0):P0 = 1: IF I >127 THEN P0 = 0:I = I -128
660 IF P0 THEN I = I +128
670 POKE C0,I: HCOLOR= 3 *P0: FOR X0 = 0 TO 6: FOR Y0 = 0 TO 4
680 IF C = CM(X0,Y0) THEN P0 = X0 *30 +30:P1 = Y0 *33 +J *4 +1: HPLOT P0,P1 TO P0,P1 +2
690 NEXT : NEXT : VTAB 14: HTAB 33: PRINT CG$:C = 0: RETURN
700 REM UPDATE SCREEN MATRIX
710 L = CS +CM(X,Y) *8 -256:X0 = 30 *X +2:Y0 = 33 *Y +1
720 FOR J = L TO L +7:I = PEEK(J): HCOLOR= 0: IF I >127 THEN I = I -128: HCOLOR= 3
730 HPLOT X0 +28,Y0 TO X0 +28,Y0 +2: FOR K = 6 TO 0 STEP -1: HCOLOR= 0: IF I >63 THEN I = I -64: HCOLOR= 3
740 DRAW 1 AT X0 +K *4,Y0:I = I *2: NEXT :Y0 = Y0 +4: NEXT : RETURN
750 REM SAVE CHARACTER SET
760 IF CS$ = "" THEN 790
770 VTAB 23: HTAB 1: PRINT "SAVE AS: ";CS$;
780 INPUT "? ";A$: IF LEFT$(A$,1) = "Y" THEN 810
790 VTAB 23: HTAB 1: INPUT "NAME TO SAVE? ";CS$
800 IF CS$ = "" THEN 812
810 PRINT D$;"BSAVE";CS$;",A";CS;",L$300"
811 REM IS HE SURE?
812 VTAB 23: HTAB 1: PRINT CHR$(6);: INPUT "DO YOU REALLY WISH TO QUIT? ";A$
814 IF LEFT$(A$,1) = "Y" THEN 820
816 VTAB 23: HTAB 1: PRINT CHR$(6);
818 IF SH = 0 THEN PRINT CHR$(11);: REM FIX CASE
819 GOTO 300
820 REM END
830 PRINT CHR$(26); CHR$(16);: REM RESET & CLEAR SCREEN
840 END
850 REM INPUT PARAMETERS
860 VTAB 10: INPUT "CHARACTER SET TO EDIT? ";CS$
870 IF LEN(CS$) >29 THEN PRINT CHR$(7);: GOTO 860
880 IF CS$ = "" THEN RETURN
890 PRINT D$;"BLOAD";CS$;",A";CS: RETURN
900 REM DRAW SCREEN
910 PRINT CHR$(16);
920 HCOLOR= 1: FOR X = 0 TO 6: FOR Y = 0 TO 4:X0 = 30 *X +1:Y0 = 33 *Y
930 FOR I = X0 TO X0 +28 STEP 4: HPLOT I,Y0 TO I,Y0 +32: NEXT
940 FOR I = Y0 TO Y0 +32 STEP 4: HPLOT X0,I TO X0 +28,I: NEXT : NEXT : NEXT
950 VTAB 9: HTAB 33: PRINT "LETTERS": VTAB 20: HTAB 33: PRINT "GRAPHIC"
960 HCOLOR= 2:X0 = 52:Y0 = 41
970 X = 222: FOR Y = 15 TO 103 STEP 88: HPLOT X,Y TO X +X0,Y: HPLOT TO X +X0,Y +Y0: HPLOT TO X,Y +Y0: HPLOT TO X,Y: NEXT
980 VTAB 23: PRINT "PRESS CONTROL-I TO DISPLAY INSTRUCTIONS": GOSUB 1070:XP = 49/256:YP = 40/256
990 C = ASC(" "): FOR X = 0 TO 6: FOR Y = 0 TO 4:CM(X,Y) = C: NEXT : NEXT :X = 0:Y = 0: VTAB 3: HTAB 33: PRINT CU$
1000 REM GRAPHIC STRING WINDER
1010 CG$ = CHR$(2) + CHR$(1) +"1": FOR Y0 = 0 TO 4: FOR X0 = 0 TO 6:CG$ = CG$ + CHR$(CM(X0,Y0)): NEXT
1020 CG$ = CG$ + CHR$(3): NEXT :CG$ = CG$ + CHR$(4): VTAB 14: HTAB 33: PRINT CG$:X0 = FRE(0): RETURN
1030 REM UPDATE STRING MATRIX
1040 CM(X,Y) = C: VTAB 3 +Y: HTAB 33 +X: PRINT CU$;: HTAB 33 +X: PRINT CHR$(C)
1050 GOSUB 700:X = X +1: IF X >6 THEN X = 0:Y = Y +1: IF Y >4 THEN Y = 0
1060 VTAB 3 +Y: HTAB 33 +X: PRINT CU$: GOSUB 1000: RETURN
1070 REM UPPER CASE
1080 SH = 0: VTAB 11: HTAB 33: PRINT "": RETURN
1090 REM LOWER CASE
1100 SH = 1: VTAB 11: HTAB 33: PRINT "": RETURN
1120 REM BACKSPACE
1130 VTAB 3 +Y: HTAB 33 +X: PRINT CU$
1140 X = X -1: IF X <0 THEN X = 6:Y = Y -1: IF Y <0 THEN Y = 4
1150 VTAB 3 +Y: HTAB 33 +X: PRINT CU$: RETURN
1160 REM FORWARD SPACE
1170 VTAB 3 +Y: HTAB 33 +X: PRINT CU$
1180 X = X +1: IF X >6 THEN X = 0:Y = Y +1: IF Y >4 THEN Y = 0
1190 VTAB 3 +Y: HTAB 33 +X: PRINT CU$: RETURN
1200 REM CARRIAGE RETURN
1210 VTAB 3 +Y: HTAB 33 +X: PRINT CU$
1220 X = 0:Y = Y +1: IF Y >4 THEN Y = 0
1230 VTAB 3 +Y: HTAB 33 +X: PRINT CU$: RETURN
1240 REM SAME CHARACTER IMAGE
1250 L = CS +CM(X,Y) *8 -256
1260 VTAB 23: HTAB 1: PRINT "SAME IMAGE FOR WHICH CHARACTER? "; CHR$(7);
1270 GET A$:C = ASC(A$): IF C <33 THEN C = 0: GOTO 1370
1280 IF SH AND C >63 AND C <96 THEN C = C +32
1290 PRINT CHR$(C)
1300 K = CS +C *8 -256:J = 0: FOR I = K TO K +7: IF PEEK(I) THEN J = 1
1310 NEXT : IF J THEN 1340
1320 REM ACCEPT CHARACTER
1330 FOR I = 0 TO 7: POKE K +I, PEEK(L +I): NEXT
1331 REM UPDATE SCREEN MATRIX
1332 SX = X:SY = Y
1333 FOR Y = 0 TO 4: FOR X = 0 TO 6
1334 IF CM(X,Y) = C THEN GOSUB 700
1335 NEXT X,Y
1338 X = SX:Y = SY: GOTO 1370
1340 REM REJECT CHARACTER
1350 VTAB 23: PRINT "'"; CHR$(C);"' IS ALREADY IN USE."; CHR$(7)
1360 C = 0: FOR I = 1 TO 1000: NEXT
1370 REM EXIT
1380 VTAB 23: PRINT CS$; CHR$(6);: RETURN
1390 REM INITIALIZE
1392 REM CHECK PADDLES
1394 IF ( PEEK( -16287) <128) OR ( PEEK( -16286) <128) THEN 1400
1396 PRINT "YOU MUST PLUG THE PADDLES IN"
1398 STOP
1400 PRINT CHR$(4);"BLOAD RBOOT": CALL 520
1405 ADRS = USR(0),"HRCG"
1406 POKE 216,0: REM ON ERR OFF
1407 IF ADRS < = 0 THEN ADRS = ADRS +65536
1410 CS = ADRS -768: HIMEM: CS
1415 CH = INT(CS/256):CL = CS -256 *CH
1420 POKE ADRS +7,CL: POKE ADRS +8,CH: CALL ADRS +3: REM INIT HRCG
1425 PRINT CHR$(16)
1430 VTAB 2: PRINT "ANIMATRIX: HI-RES CHARACTER SET EDITOR "
1435 PRINT "VERSION 1.0": PRINT
1440 PRINT "COPYRIGHT JULY 1979 APPLE COMPUTER INC."
1450 FOR I = CS TO CS +767: POKE I,0: NEXT
1460 DIM CM(6,4)
1470 KB = -16384:KS = -16368:S0 = -16287:S1 = -16286
1480 CU$ = CHR$(15) + CHR$(3) + CHR$(127) + CHR$(15) + CHR$(16): REM CURSOR
1485 D$ = CHR$(4): REM FOR DOS ACCESS
1490 POKE 232,0: POKE 233,3: POKE 768,2: POKE 769,0: POKE 770,6: POKE 771,0: POKE 772,14: POKE 773,0: REM SHAPE TABLE
1500 POKE 774,45: POKE 775,54: POKE 776,63: POKE 777,44: POKE 778,151: POKE 779,13: POKE 780,5: POKE 781,0: REM BLOCK
1510 POKE 782,13: POKE 783,30: POKE 784,23: POKE 785,13: POKE 786,21: POKE 787,0: REM CROSS
1520 SCALE= 1: ROT= 0
1530 RETURN
1610 REM
1620 POKE -16299,0: GET A$: POKE -16300,0: GOTO 300
1660 REM
1670 PRINT O$B$;: POKE -16299,0: HGR2
1700 REM
1730 A$ = CHR$(1)
1770 PRINT P$
1780 PRINT "CHARACTER SET";
1790 HTAB 40 - LEN(CS$): PRINT CS$
1800 PRINT K$;
1810 HCOLOR= 6
1820 HPLOT 0,20 TO 279,20
1830 CC = 279/5
1840 FOR CX = CC TO 279 -CC STEP CC
1850 HPLOT CX,20 TO CX,180
1860 HPLOT CX +1,20 TO CX +1,180
1870 NEXT CX
1880 CH = 1
1890 FOR CX = 0 TO 94 STEP 19
1900 VTAB 4
1910 FOR C1 = CX TO 18 +CX
1920 PRINT O$O$;
1930 C2 = C1 +32
1940 C$ = STR$(C2): IF LEN(C$) = 2 THEN C$ = " " +C$
1950 HTAB CH
1960 PRINT C$" ";
1970 PRINT CHR$(C2)" ";
1980 PRINT A$"1";
1990 PRINT CHR$(C2);
2000 PRINT A$"0"
2010 NEXT C1
2020 CH = CH +8
2030 NEXT
2040 PRINT O$P$;
2050 VTAB 24: PRINT "PRESS THE SPACE BAR TO CONTINUE...";: GET A$
2060 POKE 230,32
2070 POKE -16300,0: GOTO 50
2100 REM INIT2
2110 K$ = CHR$(11)
2120 L$ = CHR$(12)
2130 S$ = CHR$(19)
2140 Y$ = CHR$(25)
2150 Z$ = CHR$(26)
2160 B$ = CHR$(2)
2170 W$ = CHR$(23)
2180 O$ = CHR$(15)
2190 P$ = CHR$(16)
2200 PRINT Z$O$B$P$;
2210 PRINT "HI-RES CHARACTER SET EDITOR INSTRUCTIONS"
2220 PRINT "CTRL-A : SHIFT TO UPPER CASE LETTERS"
2230 PRINT "CTRL-D : DISPLAY ENTIRE CHARACTER SET"
2240 PRINT "CTRL-I : DISPLAY EDITOR INSTRUCTIONS"
2250 PRINT "CTRL-K : "; CHR$(91);" (LEFT SQUARE BRACKET)"
2260 PRINT "CTRL-L : "; CHR$(92);" (BACKSLASH)"
2265 PRINT "CTRL-O : "; CHR$(95);" (UNDERSCORE)"
2270 PRINT "CTRL-S : ASSIGN SAME CHARACTER IMAGE"
2280 PRINT "CTRL-T : TOGGLE HIGH BIT (1/2 DOT SHIFT)";
2295 PRINT "CTRL-Z : SHIFT TO LOWER CASE LETTERS"
2300 PRINT "ESCAPE : QUIT AND SAVE CHARACTER SET": PRINT
2310 PRINT "PADDLE 0 MOVES THE CURSOR HORIZONTALLY,"
2320 PRINT "PADDLE 1 MOVES THE CURSOR VERTICALLY."
2330 PRINT "BUTTON 0 TURNS GRAPHIC DOTS (BITS) OFF,"
2340 PRINT "BUTTON 1 TURNS THEM ON. THE KEYBOARD"
2350 PRINT "CONTROLS ALL OTHER EDITING FEATURES.": PRINT
2360 PRINT "TO ENTER LETTERS TO BE EDITED, SIMPLY"
2370 PRINT "TYPE THEM ON THE KEYBOARD, OR USE THE"
2380 PRINT "FORWARD & BACK ARROWS AND RETURN KEY."
2390 VTAB 24: PRINT "PRESS THE SPACE BAR TO CONTINUE...";Z$;: RETURN
3000 PRINT "UNABLE TO LOAD RBOOT, RLOAD OR HRCG."
3020 POKE 216,0: STOP
10000 REM JULY 1979 BY CHARLIE KELLNER, APPLE COMPUTER INC.

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/ASIF.GAMES.txt:

0288
2S AA.E.
AABM
AAIRCARS
1S FALI BABA
1S GALIEN
AALIEN AMBUSH
AALIEN TYPHOON
1F AAPE ESCAPE
1S TAPPLE ADVENTURE
AAPPLE GALAXIAN
AAPPLE PANIC
AAPPLE-OIDS
1S FAPVENTURE TO ATLANTIS
AAQUATRON
2S MARCADE MACHINE
1S AARGOS
1S AARTESIANS
AASTEROID FIELD
AAUTOBAHN
1F AAXIS ASSASSIN
1S MAZTEC
1S ABANDITS
1F ABASKETBALL (DR.J:LARRY BIRD)
1F ABATS IN THE BELFRY
1F ABEER RUN
1F ABELLHOP
1F GBENEATH APPLE MANOR (GRAPHIC)
ABEZ MAN
1F ABILESTOAD
1S ABLACK BELT
1F1S GBLADE OF BLACKPOOLE
ABOLO
1F ABOUNCING KAMUNGAS
ABRAINTEASER BLVD
ABUG ATTACK
1F ABURGERTIME
1F ACANNONBALL BLITZ
ACANYON CLIMBER
ACARNIVAL
1S SCASTLE WOLFENSTEIN
1S ACAVERN CREATURES
1S ACAVERNS OF CALLISTO
FCAVERNS OF FREITAG
ACEILING ZERO
1F ACENTIPEDE (ATARI)
1F SCHINESE CHESS
ACHIP OUT
1S MCHIVALRY
ACHOPLIFTER
ACOLLECT
MCOMBAT
ACOMPUTER FOOSBALL
ACONGO
ACOSMIC JUGGLER
2S GCOVETED MIRROR, THE
1S GCRANSTON MANOR
1F ACRAZY MAZEY
1S GCREATURE VENTURE
ACRIME WAVE
1S ACRISIS MOUNTAIN
1F1S GCRITICAL MASS
1F ACROSS COUNTRY RALLY
1S ACROSSFIRE
ACUBIT
1S TCYBORG
4S GDARK CRYSTAL
1S SDARK FOREST
ADAVID'S MIDNIGHT MAGIC
2S GDEATH IN THE CARIBBEAN
MDEATHMAZE
1F ADEFENDER (ATARI)
ADEFENDER (JOE HOLT)
ADEFENSE CRUISER
1S GDEMON'S FORGE
1S MDESECRATION, THE
ADIAMOND MINE
ADIG 'EM
ADIG DUG
1S ADINO-EGGS
1S ADONKEY KONG (ATARI)
SDRAW POKER
1S ADROL
1F ADUELING DIGITS
ADUNG BEETLES
2S GEARTHQUAKE
TEMPIRE OF THE OVERMIND
AEPOCH
1S GESCAPE FROM RUNGISTAN
1S AEVOLUTION
AFALCONS ][
1S AFAT CITY
AFATHOM ATTACK
AFENDER BENDER
1F AFIRE AND ICE
1S SFLIGHT SIMULATOR ][
1F AFLIP OUT
1F AFORMULA 1 RACER
1F AFRAZZLE
AFREE FALL
AFRENZY
AFROGGER(K)
AGAMMA GOBLINS
AGENETIC DRIFT
SGO
AGOBBLER
AGOLD RUSH
AGORGON
AGRAN PRIX
1F1S GGRUDS IN SPACE
1F AGUARDIAN
AGUMBALLS
AHADRON
1S AHALLOWE'EN
1F AHARD HAT MACK
1S AHELICOPTER RESCUE
AHELLSTORM
1S AHIEST, THE
AHIGHRISE
AHORIZON V
AHOWITZER BATTLE
AHUMAN FLY
AJAWBREAKER
AJAWBREAKER II
AJOUSTER
AJUMP JET
2S AJUMPMAN
1S MJURY TRIAL
2S GKABUL SPY
AKAMIKAZE
AKLAN COOKOUT
2S FKNIGHT OF DIAMONDS, THE
ALABYRINTH
ALADY TUT
ALAF PACK
ALASER SILK
2S FLEGACY OF LLYLGAMN
ALEMMINGS
1F ALOCK & CHASE
1S ALODE RUNNER
1S FLORDLINGS OF YORE
1S ALUNAR LEEPERS
1F SMAHJONG
1S AMARAUDER
1F AMARS CARS
1S AMATING ZONE
1F MMAZE CRAZE SET
1S AMICROBE
AMICROWAVE
AMINER
1S AMINER 2049'ER
1F AMINES OF MALZEB
1F AMINIT MAN
AMISSILE DEFENSE
1S FMISSING RING, THE
1S GMISSION ASTEROID
AMONSTER MASH
AMOUSKATTACK
1F AMR. COOL
1S GMUMMY'S CURSE
1S GMYSTERY HOUSE
ANEPTUNE
1S MNEW WORLD
ANIGHT DRIVER
ANIGHT MISSION
ANIGHT STALKER
ANIGHTCRAWLER
ANIGHTMARE GALLERY
1F ANORAD
AO'RILEYS MINE
1S FODYSSEY
1F MOIL TYCOON
1S AOLYMPIC DECATHLON
AOUTPOST
APACMAN (ATARI)
1F APANDORA'S BOX
APEGASUS II
1F APEST PATROL
1F APHANTOMS FIVE
APHAZOR FIRE
APHOTAR
1F APICNIC PARANOIA
1F APIE MAN
APILL BOX
1F APINBALL (BILL BUDGE)
1S MPINBALL CONSTRUCTION
1F APLANETOIDS
1F APLASMANIA
MPOLICE ARTIST
1F APOOYAN
1S GPRISONER ][
1F APROCYON WARRIOR
APUCK MAN
AQUADRANT 6112
1F AQUEST FOR TIRES
2S GQUEST, THE
3S FQUESTRON
1S GRACE FOR MIDNIGHT
ARAINBOW ZONE
ARASTER BLASTER
1F AREARGUARD
1F ARED ALERT
1S AREPTON
1F ARIBBIT
1F AROADBLOCK
AROBOT BATTLE
1F AROBOTRON 2084 (ATARI)
AROCKET COMMAND
1S MROCKY'S BOOTS
ARUSKI DUCK
1F ASABOTAGE
2S GSAGA #1
1S ASAMMY LIGHTFOOT
1S GSANDS OF EGYPT, THE
1F SSARGON I
1F SSARGON II
1S SSARGON III
1S ASEA DRAGON
ASEA WOLF
ASEAFOX
1S GSECRET AGENT
2S GSERPENT'S STAR, THE
1F ASHAMUS
1S GSHERWOOD FOREST
1F ASHUTTLE INTERCEPT
ASNACK ATTACK
ASNAKE BYTE
ASNAPPER, THE
ASNEAKERS
ASPACE CADET
ASPACE EGGS
1F ASPACE RAIDERS
1S ASPACE SPIKES
1F ASPACE WAR (BILL BUDGE)
1F ASPACE WARRIOR
1S ASPUD & MUG SHOT
1F ASPY'S DEMISE
2S FSTANDING STONES, THE
1F ASTAR BLASTER
1F ASTAR BLAZER
ASTAR CLONES
ASTAR THIEF
1F ASTAR TREK
1F ASTAR VENTURE
1F ASTARGATE
1F ASTARMAZE
1S SSTARSHIP COMMANDER
1S ASTELLER 7
ASUBMARINE COMMANDER
ASUICIDE
1S ASUPER BUNNY
1S ASUPER PAC-GAL
1S ASUPER TAXMAN ][
1S ASWASHBUCKLER
STAIPAN
1S ATALON
2F ATANK WARS
1F ATAXMAN
1S FTEMPLE OF APSHAI
1F MTEXTTRAIN
1S FTHESEUS AND THE MINOTAUR
1F ATHIEF
1S ATHRESHOLD
1F ATHUNDER BIRD
1F ATHUNDERBOMBS
1S GTRANSYLVANIA
1S ATRIPLE ARCADE INSANITY
ATUBEWAY
ATUNNEL TERROR
ATWERPS
2S FULTIMA I
3S FULTIMA II
2S FULTIMA III
1F AVINDICATOR
AVIPER
AVORTEX
AWARGLE
AWARLORDS
1S AWARP DESTROYER
1S AWAVY NAVY
1S AWAY OUT
1S GWIZARD AND THE PRINCESS, THE
2S FWIZARDRY
AWORM WALLS
1S AZAXXON
1F AZENITH
1S TZORK I
1S TZORK II
1S TZORK III

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/ASIF.NON-GAMES.txt:

0112
H3-D GRAPHICS (BILL BUDGE)
HACCU-SHAPES
HALPHA PLOT
KANSWERING MACHINE, THE
UAPPLE MECHANIC
WAPPLE WRITER ][
UAPPLE-WRITER II, PREBOOT 80-CL
HARTIST, THE
KASCII EXPRESS PRO. 3.46
KASCII EXPRESS PRO. 4.20
CBACK IT UP II+
CBACK-IT-UP (NITTY-GRITTY)
UBAG OF TRICKS
WBANK STREET WRITER
UBEAGLE BASIC
KCAT'S MEOW, THE
KCATHACKER
CCLONE
CCLONE II
CCLONE KIT 2.0
KCOMWARE 5.03
CCOPY II
CCOPY II PLUS
CCOPY II+ 3.1
CCOPY II+ 4.3 BIT COPIER
CCOPY II+ 4.3 UTILITIES
KDFX II
CDISK MUNCHER 1.1
UDISK RIGGER 1.0
UDISK SPLITTER 2.0
UDISK SPLITTER 2.01
KDISK-FER
UDOS BOSS
UDOS TOOL KIT
UDOUBLE-TAKE
HE-Z DRAW 3.3
CECHO
PEPSON SCREEN DUMPER
CESSENTIAL DATA DUPLICATOR V2
CESSENTIAL DATA DUPLICATOR V3
XFAMOUS SEX COMICS #1
CFAST
CFID 1DRIVE
UFLEX-TEXT
QFORTE'
XFRENCH POSTCARDS
UGLOBAL PROGRAM LINE EDITOR
JGLOBE MASTER
LGRAFORTH ][
HGRAPHIC MAGICIAN (NEW)
HGRAPHIC SOLUTION, THE
HGRAPHICS MAGICIAN (OLD)
PGRAPHTRIX 1.2
XHANDS ON
HHIGHER FONTS
HHIGHER TEXT
WHOMEWORD
CKOPY ROM
CLOCKSMITH 3.0
CLOCKSMITH 3.1
CLOCKSMITH 3.2
CLOCKSMITH 4.1
CLOCKSMITH 4.3
CLOCKSMITH 5.0
WMAGIC WINDOW
WMAGIC WINDOW II
EMERLIN
MMICRO COOKBOOK
UMULTI-DISK CATALOGING SYSTEM
EMUNCH-A-BUG
QMUSIC COMPOSER (APPLE-CAT)
QMUSIC CONSTRUCTION SET
QMUSIC MAKER
QMUSIC SYNTHESIZER (APPLE-CAT)
CNIBBLES AWAY
CNIBBLES AWAY II
CPENULTI COPY
BPFS: FILE
BPFS: REPORT
JPHYSICS BY PLATO
WPIE WRITER
CPIRATES FRIEND
HPOOR MAN'S GRAPHIC TABLET
DPRODOS
DPRONTO-DOS
JPSAT:PREFIXES BY EDU-WARE
JSAT :ENGLISH #1 BY MICROLAB
JSAT :ENGLISH,MATH BY HBJ, INC.
JSAT :VOCAB BY KRELL
JSAT:MATH1-13,READ. COMP. KRELL
JSAT:PREFIXES,ROOTS BY EDU-WARE
USCANNER
XSEX-RATED
USILICON SALAD
MSOFT SWAP
1S QSONGWRITER
HSPECIAL EFFECTS
USPEEDREAD +
XSTRIP BLACKJACK
CSUPER DISK COPY 3.6
CSUPER DISK COPY 3.7
CSUPER DISK COPY 3.8
UTASC COMPILER
MTIP DISK #1
HTRANSITIONS
HTYPEFACES
UUTILITY CITY
BVISICALC
BVISIDEX
BVISIFILE
KVOICE SYNTHESIZER III
PZOOM GRAFIX

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/ASMIDSTAMP.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 B2 B9 AD CE CF D6 AD B7 B9 A0 A3 B0 B0 B0 B0 B0 29-NOV-7 9 #00000
$000010 B0 .. .. .. .. .. .. .. .. .. .. .. .. .. .. .. 0
** END **

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/EDASM.bas:

100 TEXT : HOME :D$ = CHR$(4)
110 F$ = "ASMIDSTAMP"
120 PRINT D$;"NOMON C,I,O"
130 PRINT D$;"BLOAD ";F$;",A$3B8"
140 VTAB 3: PRINT "APPLE ][ EDITOR-ASSEMBLER"
150 VTAB 5: PRINT "CURRENT ASSEMBLER ID STAMP IS:"
160 VTAB 7: HTAB 1
170 FOR I = 952 TO 968: PRINT CHR$( PEEK(I));: NEXT
180 VTAB 7: HTAB 1: INPUT "";A$:L = LEN(A$)
190 IF L <17 THEN VTAB 7: HTAB L +1: FOR I = L TO 16: PRINT CHR$( PEEK(952 +I));: NEXT : PRINT
200 IF L = 0 THEN 240
210 IF L >17 THEN L = 17
220 FOR I = 1 TO L: POKE 951 +I, ASC( MID$ (A$,I,1)) +128: NEXT
230 PRINT D$;"BSAVE ";F$;",A$3B8,L$11"
240 PRINT D$;"BRUN EDASM.OBJ"
250 END

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/HELLO.bas:

100 TEXT : HOME
110 VTAB 3: PRINT "DOS TOOL KIT"; TAB( 30);"VERSION 1.0"
120 VTAB 5: PRINT "(C) COPYRIGHT 1980, APPLE COMPUTER INC."
130 PRINT : PRINT
140 END

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/INTEDASM.int:

100 TEXT :CALL -936
110 DIM A$(40),F$(10)
120 D$="":F$="ASMIDSTAMP"
130 PRINT D$;"NOMON C,I,O"
140 PRINT D$;"BLOAD ";F$;",A$3B8"
150 VTAB 3:PRINT "APPLE ][ EDITOR-ASSEMBLER"
160 VTAB 5:PRINT "CURRENT ASSEMBLER ID STAMP IS:"
170 VTAB 7:TAB 1:BASE=256* PEEK (41)+ PEEK (40)
180 FOR I=0 TO 16: POKE BASE+I, PEEK (952+I):NEXT I
190 VTAB 7:TAB 1:INPUT A$:L= LEN(A$)
200 IF L>17 THEN L=17
210 IF L=17 THEN 240
220 FOR I=L TO 16: POKE BASE+I, PEEK (952+I):NEXT I
230 IF L=0 THEN 260
240 FOR I=1 TO L: POKE 951+I, ASC(A$(I,I)):NEXT I
250 PRINT D$;"BSAVE ";F$;",A$3B8,L$11"
260 PRINT D$;"BRUN EDASM.OBJ"
270 END

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/KATAKANA.SET.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 00 00 00 00 00 00 00 00 00 00 00 00 0E 0A 0E 00 ........ ........
$000010 38 08 08 08 00 00 00 00 00 00 00 08 08 08 0E 00 8....... ........
$000020 00 00 00 00 02 04 08 00 00 00 00 0C 0C 00 00 00 ........ ........
$000030 00 3E 20 3E 20 10 08 00 00 00 3E 20 18 08 04 00 .> > ... ..> ....
$000040 00 00 10 08 0C 0A 08 00 00 00 08 3E 22 20 18 00 ........ ...>" ..
$000050 00 00 00 3E 08 08 3E 00 00 00 10 3E 18 14 12 00 ...>..>. ...>....
$000060 00 00 04 3E 24 14 04 00 00 00 00 1C 10 10 3E 00 ...>$... ......>.
$000070 00 00 3E 20 3E 20 3E 00 00 00 00 2A 2A 20 18 00 ..> > >. ...** ..
$000080 00 00 00 3E 00 00 00 00 3E 20 28 18 08 08 04 00 ...>.... > (.....
$000090 20 10 08 0C 0A 08 08 00 08 3E 22 22 20 10 08 00 ....... .>"" ...
$0000A0 00 3E 08 08 08 08 3E 00 10 3E 10 18 14 12 10 00 .>....>. .>......
$0000B0 04 3E 24 24 24 24 12 00 08 3E 08 3E 08 08 08 00 .>$$$$.. .>.>....
$0000C0 00 3C 24 22 20 10 0C 00 04 3C 12 10 10 10 08 00 .<$" ... .<......
$0000D0 00 3E 20 20 20 20 3E 00 14 3E 14 14 10 08 04 00 .> >. .>......
$0000E0 00 06 20 26 20 10 0E 00 00 3E 20 10 08 14 22 00 .. & ... .> ...".
$0000F0 04 3E 24 14 04 04 38 00 00 22 22 24 20 10 0C 00 .>$...8. .""$ ...
$000100 00 3C 24 2A 30 10 0C 00 10 0E 08 3E 08 08 04 00 .<$*0... ...>....
$000110 00 2A 2A 2A 20 10 08 00 1C 00 3E 08 08 08 04 00 .*** ... ..>.....
$000120 04 04 04 0C 14 04 04 00 08 08 3E 08 08 04 02 00 ........ ..>.....
$000130 00 1C 00 00 00 00 3E 00 00 3E 20 14 08 14 02 00 ......>. .> .....
$000140 08 3E 10 08 1C 2A 08 00 10 10 10 10 10 08 04 00 .>...*.. ........
$000150 00 00 14 24 24 24 22 00 02 02 3E 02 02 02 3C 00 ...$$$". ..>...<.
$000160 00 3E 20 20 20 10 0C 00 00 04 0A 10 20 20 00 00 .> ... .... ..
$000170 08 08 3E 08 2A 2A 08 00 00 3E 20 20 14 08 10 00 ..>.**.. .> ....
$000180 00 1C 00 1C 00 1E 20 00 00 08 04 02 22 3E 20 00 ...... . ...."> .
$000190 00 20 20 14 08 14 02 00 00 3E 04 3E 04 04 38 00 . ..... .>.>..8.
$0001A0 04 04 3E 24 14 04 04 00 00 1C 10 10 10 10 3E 00 ..>$.... ......>.
$0001B0 00 3E 20 3E 20 20 3E 00 1C 00 3E 20 20 10 08 00 .> > >. ..> ...
$0001C0 22 22 22 22 20 10 08 00 00 08 0A 0A 2A 2A 1A 00 """" ... ....**..
$0001D0 00 02 02 22 12 0A 06 00 00 3E 22 22 22 22 3E 00 ...".... .>"""">.
$0001E0 00 3E 22 22 20 10 08 00 00 06 00 20 20 10 0E 00 .>"" ... ... ...
$0001F0 08 12 04 00 00 00 00 00 0E 0A 0E 00 00 00 00 00 ........ ........
$000200 00 3C 24 2A 30 10 0C 00 10 0E 08 3E 08 08 04 00 .<$*0... ...>....
$000210 00 2A 2A 2A 20 10 08 00 1C 00 3E 08 08 08 04 00 .*** ... ..>.....
$000220 04 04 04 0C 14 04 04 00 08 08 3E 08 08 04 02 00 ........ ..>.....
$000230 00 1C 00 00 00 00 3E 00 00 3E 20 14 08 14 02 00 ......>. .> .....
$000240 08 3E 10 08 1C 2A 08 00 10 10 10 10 10 08 04 00 .>...*.. ........
$000250 00 00 14 24 24 24 22 00 02 02 3E 02 02 02 3C 00 ...$$$". ..>...<.
$000260 00 3E 20 20 20 10 0C 00 00 04 0A 10 20 20 00 00 .> ... .... ..
$000270 08 08 3E 08 2A 2A 08 00 00 3E 20 20 14 08 10 00 ..>.**.. .> ....
$000280 00 1C 00 1C 00 1E 20 00 00 08 04 02 22 3E 20 00 ...... . ...."> .
$000290 00 20 20 14 08 14 02 00 00 3E 04 3E 04 04 38 00 . ..... .>.>..8.
$0002A0 04 04 3E 24 14 04 04 00 00 1C 10 10 10 10 3E 00 ..>$.... ......>.
$0002B0 00 3E 20 3E 20 20 3E 00 1C 00 3E 20 20 10 08 00 .> > >. ..> ...
$0002C0 22 22 22 22 20 10 08 00 00 08 0A 0A 2A 2A 1A 00 """" ... ....**..
$0002D0 00 02 02 22 12 0A 06 00 00 3E 22 22 22 22 3E 00 ...".... .>"""">.
$0002E0 00 3E 22 22 20 10 08 00 00 06 00 20 20 10 0E 00 .>"" ... ... ...
$0002F0 08 12 04 00 00 00 00 00 0E 0A 0E 00 00 00 00 00 ........ ........
** END **

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/LOADAPA.bas:

100 REM PROGRAM TO LOAD APA
110 HOME
120 ONERR GOTO 340
130 ADRS = 0
140 PRINT CHR$(4),"BLOAD RBOOT"
150 CALL 520: REM EXECUTE RBOOT
160 ADRS = USR(0),"APA"
170 REM BRING IN APA, ADRS=STARTING ADDRESS
180 CALL ADRS: REM INITIALIZE APA
190 PRINT : PRINT
200 PRINT "&RENUMBER ,,,"
210 PRINT "&HOLD"
220 PRINT "&MERGE"
230 PRINT "&LENGTH"
240 PRINT "&COMPRESS"
250 PRINT "&SHOW"
260 PRINT "&NOSHOW"
270 PRINT "&AUTO ,"
280 PRINT "&MANUAL"
290 PRINT "&XREF"
300 PRINT "&KEYS"
310 PRINT : PRINT
320 POKE 216,0: REM ON ERR OFF
330 END
340 PRINT "UNABLE TO LOAD"
350 POKE 216,0: REM ON ERR OFF
360 END

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/LOADHRCG.bas:

100 REM PROGRAM TO LOAD HRCG
110 ONERR GOTO 330
120 ADRS = 0
130 PRINT CHR$(4);"BLOAD RBOOT"
140 CALL 520: REM EXECUTE RBOOT
150 ADRS = USR(0),"HRCG"
160 REM BRING IN HRCG, ADRS=STARTING ADDRESS
170 PRINT "HOW MANY ALTERNATE CHARACTER SETS"
180 INPUT "WOULD YOU LIKE (0-9)? ";A
190 IF (A <0) OR (A >9) THEN 170
200 IF A = 0 THEN 300
210 IF ADRS < = 0 THEN ADRS = ADRS +65536: REM MAKE ADRS POSITIVE
220 CS = ADRS -768 *A: HIMEM: CS
230 CH = INT(CS/256):CL = CS -256 *CH
240 POKE ADRS +7,CL: POKE ADRS +8,CH
250 FOR I = 1 TO A
260 PRINT "NAME OF CHARACTER SET ";I;
270 INPUT CN$
280 PRINT CHR$(4);"BLOAD ";CN$;",A";CS +(I -1) *768: REM LOAD IN SET
290 NEXT I
300 CALL ADRS: REM INITIALIZE HRCG
310 POKE 216,0: REM ONERR OFF
320 END
330 PRINT "UNABLE TO LOAD"
340 POKE 216,0: REM ON ERR OFF
350 END

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/MAXWELL.bas:

10 REM MAXWELL'S DEMO
20 REM COPYRIGHT 1980 BY APPLE COMPUTER INC.
30 REM BRING IN FILES AND INITIALIZE HRCG
40 GOSUB 2000
50 REM RUN 50 TO RESTART
60 SPEED= 255
70 PRINT CHR$(15); CHR$(20); CHR$(16);
80 GOSUB 1000
90 X = 38:Y = 10
100 REM WALK ONSTAGE
110 W = 60
120 I = 16: GOSUB 900
130 I = 17: GOSUB 900
140 X = X -1:I = 18: GOSUB 900
150 IF X >1 THEN 120
200 REM WAVE ARMS
210 W = 100
220 FOR C = 1 TO 20
230 I = INT( RND(1) *12) +1
240 GOSUB 900: NEXT
250 FOR I = 1 TO 6: GOSUB 900: NEXT
300 REM LECTURE
310 FOR J = 1 TO 500: NEXT
330 SPEED= 100
340 VTAB 15: HTAB 10
350 PRINT "LADIES AND GENTLEMEN...": PRINT
360 PRINT "APPLE COMPUTER INC. IS PROUD TO PRESENT"
370 PRINT "MAXWELL_______, A SMALL DEMONSTRATION OF HI-RES"
380 PRINT "PROGRAMMABLE CHARACTER SET ANIMATION !!!"
390 SPEED= 255
400 REM WALK OFFSTAGE
410 W = 40: FOR I = 6 TO 1 STEP -1: GOSUB 900: NEXT
420 FOR J = 1 TO 200: NEXT
430 I = 13: GOSUB 900
440 I = 14: GOSUB 900
450 X = X +1:I = 15: GOSUB 900
460 IF X <38 THEN 430
470 I = 1: GOSUB 900
480 FOR J = 1 TO 500: NEXT
500 REM WALK ONSTAGE
510 W = 1
520 I = 16: GOSUB 900
530 I = 17: GOSUB 900
540 X = X -1:I = 18: GOSUB 900
550 IF X >1 THEN 520
700 REM WALK OFFSTAGE
710 W = 60: FOR J = 1 TO 200: NEXT
730 I = 13: GOSUB 900
740 I = 14: GOSUB 900
750 X = X +1:I = 15: GOSUB 900
760 IF X <38 THEN 730
770 FOR I = 7 TO 12: GOSUB 900: NEXT
780 FOR J = 1 TO 500: NEXT
800 REM END
820 POKE -16368,0
830 VTAB 23: HTAB 1
840 PRINT CHR$(15); CHR$(16);
850 END
900 REM PRINT
910 VTAB Y: HTAB X: PRINT M$(I);
920 FOR J = 1 TO W: NEXT : RETURN
1000 M = 18: DIM M$(M)
1005 M$(0) = "1 "
1010 M$(1) = "1DAGEBHFC "
1020 M$(2) = "1DAGEBRFC "
1030 M$(3) = "1DASEBTFC "
1040 M$(4) = "1DAUEB FC "
1050 M$(5) = "1DAVEB FC "
1060 M$(6) = "1DAWEB FC "
1070 M$(7) = "1DAGEBHFC "
1080 M$(8) = "1KAGIBHFC "
1090 M$(9) = "1LAGJBHFC "
1100 M$(10) = "1NAGMBHFC "
1110 M$(11) = "1OAGMBHFC "
1120 M$(12) = "1PAGMBHFC "
1130 M$(13) = "1 A BC DE"
1140 M$(14) = "1 FG HI JK"
1150 M$(15) = "1LM NOPQR "
1160 M$(16) = "1 S TU VW "
1170 M$(17) = "1XY Z0 12 "
1180 M$(18) = "1 34567 89"
1990 RETURN
2000 REM INITIALIZE HRCG
2010 ONERR GOTO 2500
2020 TEXT : HOME : HGR :ADRS = 0
2030 PRINT CHR$(4);"BLOAD RBOOT": CALL 520: REM BRING IN RLOAD
2040 ADRS = USR(0),"HRCG"
2050 POKE 216,0: REM TURN OFF ON ERR
2060 IF ADRS <0 THEN ADRS = ADRS +65536: REM MAKE ADRS POSITIVE
2070 CS = ADRS -768: HIMEM: CS: REM MAKE ROOM FOR CHARACTER SET
2080 D$ = CHR$(4)
2090 PRINT D$;"BLOAD MAX.SET,A";CS: REM LOAD IN SET
2100 CH = INT(CS/256):CL = CS -CH *256: REM CHAR SET LOW BYTE & HIGH BYTE
2110 POKE ADRS +7,CL: POKE ADRS +8,CH: CALL ADRS +3: REM INIT HRCG
2120 PRINT D$;"BLOAD APPLE LOGO.PIC,A$4000": REM LOAD BACKGROUND SCREEN
2130 RETURN
2500 REM ERROR TRAP FOR RLOAD
2510 TEXT
2520 PRINT "ERROR IN RLOAD OR RBOOT"
2530 POKE 216,0
2540 STOP

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/RIBBIT.bas:

10 GOTO 10000: REM INITIALIZE
20 GOSUB 900: GOTO 1000
100 REM FLUTTER BY
120 BC = NOT BC: IF BC THEN VTAB BY: HTAB BX: PRINT BUG$((BD <0),2): RETURN
130 IF BX >1 AND BX <38 THEN 150
140 VTAB BY: HTAB BX: PRINT BUG$(0,0):BY = INT( RND(1) *8) *2 +3:BX = ( RND(1) <.5) *37 +1:BD = 1 -(BX >20) *2:BS = BS +1: GOSUB 2000
150 BX = BX +BD: VTAB BY: HTAB BX: PRINT BUG$((BD <0),1): RETURN
400 REM JUMP LEFT
410 IF FD THEN 500
420 IF FX >7 THEN FX = FX -1
430 FOR FY = 19 TO P1 +1 STEP -1: GOSUB 100: VTAB FY: HTAB FX: PRINT FROG$(0,3);: NEXT : GOSUB 1200
440 IF FX >7 THEN FX = FX -1
450 FOR FY = P1 TO 19: VTAB FY: HTAB FX: PRINT FROG$(0,4);: GOSUB 100: NEXT :FY = 19
460 VTAB FY: HTAB FX: PRINT FROG$(0,1);: RETURN
500 REM JUMP RIGHT
510 IF FX <28 THEN FX = FX +1
520 FOR FY = 19 TO P1 +1 STEP -1: GOSUB 100: VTAB FY: HTAB FX -1: PRINT FROG$(1,3);: NEXT : GOSUB 1300
530 IF FX <28 THEN FX = FX +1
540 FOR FY = P1 TO 19: VTAB FY: HTAB FX -1: PRINT FROG$(1,4);: GOSUB 100: NEXT :FY = 19
550 VTAB FY: HTAB FX: PRINT FROG$(1,1);: RETURN
600 REM HOP LEFT
610 GOSUB 100: IF FD THEN 700
620 IF FX <8 THEN FOR I = 1 TO 50: NEXT : RETURN
630 FX = FX -1: VTAB FY: HTAB FX: PRINT FROG$(0,3);: GOSUB 100: IF FX >7 THEN FX = FX -1
640 VTAB FY: HTAB FX: PRINT FROG$(0,4);: GOSUB 100
650 VTAB FY: HTAB FX: PRINT FROG$(0,1);: RETURN
700 REM HOP RIGHT
710 IF FX >27 THEN FOR I = 1 TO 50: NEXT : RETURN
720 FX = FX +1: VTAB FY: HTAB FX -1: PRINT FROG$(1,3);: GOSUB 100: IF FX <28 THEN FX = FX +1
730 VTAB FY: HTAB FX -1: PRINT FROG$(1,4);: GOSUB 100
740 VTAB FY: HTAB FX: PRINT FROG$(1,1);: RETURN
800 REM CROAK
810 VTAB 1: HTAB 16
820 PRINT " RIB*BIT ";
830 FOR W = 120 TO 80 STEP -5: POKE PT,40: POKE DR,2: CALL TN: POKE PT,W: POKE DR,3: CALL TN: NEXT
840 VTAB 1: HTAB 16
850 PRINT " RIB*BIT ";: RETURN
900 REM TURN AROUND
910 VTAB FY: HTAB FX: PRINT FROG$(FD,1);: GOSUB 100: RETURN
1000 REM MAIN LOOP
1010 FOR I = 1 TO RND(1) *400 +100: GOSUB 100
1020 P0 = PDL(0): IF P0 <80 AND FD THEN FD = 0: GOSUB 900
1030 IF P0 >160 AND NOT FD THEN FD = 1: GOSUB 900
1040 P1 = 17 - INT( PDL(1)/16)
1050 IF PEEK( -16384) = 155 THEN 9000
1060 IF PEEK( -16287) >127 THEN GOSUB 600
1070 IF PEEK( -16286) >127 THEN GOSUB 400
1080 NEXT : GOSUB 1100: GOTO 1000
1100 REM CROAK
1110 VTAB FY +4: HTAB FX +4 *FD: PRINT FROG$(FD,2);
1120 GOSUB 800
1130 VTAB FY: HTAB FX: PRINT FROG$(FD,1);: RETURN
1200 REM RIBBIT LEFT
1210 VTAB FY +2: HTAB FX: PRINT FROG$(0,2);
1220 FOR I = 1 TO 5: HTAB FX -I -1: PRINT RBT$(0,I);: POKE PT,32 -I -I: POKE DR,3: CALL TN: NEXT
1230 FOR I = 5 TO 0 STEP -1: HTAB FX -I -1: PRINT RBT$(0,I);: POKE PT,10 +I +I: POKE DR,3: CALL TN: NEXT
1240 IF (FY = BY -1 OR FY = BY -2) AND FX >BX +2 AND FX BX -12 AND FX 99 THEN 3000
2020 VTAB 1: HTAB 1
2030 PRINT "BUTTERFLIES:";: IF BS <10 THEN PRINT " ";
2040 PRINT BS;: HTAB 17
2050 PRINT "RIB*BIT ";
2060 PRINT "FREE LUNCHES:";: IF FS <10 THEN PRINT " ";
2070 PRINT FS;: RETURN
3000 REM WRAPUP
9000 REM END
9010 POKE -16368,0
9020 PRINT CHR$(26); CHR$(16);: REM CLEAR SCREEN
9090 END
10000 REM INITIALIZE
10001 REM CHECK FOR PADDLES
10002 IF ( PEEK( -16287) <128) OR ( PEEK( -16286) <128) THEN 10010
10005 PRINT "YOU MUST PLUG THE PADDLES IN"
10007 STOP
10010 TEXT : HOME : HGR : LOMEM: 24576: ONERR GOTO 30000:ADRS = 0
10020 PRINT CHR$(4);"BLOAD RBOOT": CALL 520: REM BRING IN RLOAD
10030 ADRS = USR(0),"HRCG"
10040 POKE 216,0: REM TURN OFF ON ERR
10050 IF ADRS < = 0 THEN ADRS = ADRS +65536: REM MAKE ADRS POSITIVE
10060 CS = ADRS -1536: HIMEM: CS: REM MOVE HIMEM DOWN FOR CHAR SET
10070 D$ = CHR$(4): PRINT D$;"BLOAD FROGS1.SET,A";CS: REM LOAD IN SETS
10080 PRINT D$;"BLOAD FROGS2.SET,A";CS +768
10085 CH = INT(CS/256):CL = CS -CH *256
10090 POKE ADRS +7,CL: POKE ADRS +8,CH: CALL ADRS +3: REM INIT HRCG
10100 PRINT CHR$(16): REM CLEAR SCREEN
10200 REM PICTURES
10300 BUG$(0,0) = ""
10310 BUG$(0,1) = "1&'*():"
10320 BUG$(0,2) = "1 !# $%"
10330 BUG$(1,0) = ""
10340 BUG$(1,1) = "2*'&:)("
10350 BUG$(1,2) = "2#! %$ "
10400 FROG$(0,1) = "1 ABCDEQ FGHIJKR LMNOP"
10410 FROG$(0,2) = "1HIJ"
10420 FROG$(0,3) = "1ABCS FGHIT UVIT WXYZ0 123 "
10430 FROG$(0,4) = "1 FG CDE AB ABC8I9 FG4567 "
10500 FROG$(1,1) = "2 QEDCBARKJIHGFPONML "
10510 FROG$(1,2) = "2JIH"
10520 FROG$(1,3) = "2 SCBA TIHGF TIVU 0ZYXW 321 "
10530 FROG$(1,4) = "2 GF EDC BA 9I8CBA 7654GF"
10600 RBT$(0,0) = "1 HI"
10610 RBT$(0,1) = "1 LNO"
10620 RBT$(0,2) = "1 LMNO"
10630 RBT$(0,3) = "1 LMMNO"
10640 RBT$(0,4) = "1 LMMMNO"
10650 RBT$(0,5) = "1 LMMMMNO"
10700 RBT$(1,0) = "2IH "
10710 RBT$(1,1) = "2ONL "
10720 RBT$(1,2) = "2ONML "
10730 RBT$(1,3) = "2ONMML "
10740 RBT$(1,4) = "2ONMMML "
10750 RBT$(1,5) = "2ONMMMML"
10800 REM START BUGS
10810 BY = INT( RND(1) *16) +1:BX = 1:BD = 1:BC = 1
10900 REM TONE SUBROUTINE
10910 POKE 770,32: POKE 771,74: POKE 772,255: POKE 773,173: POKE 774,48: POKE 775,192: POKE 776,136: POKE 777,208: POKE 778,5
10920 POKE 779,206: POKE 780,1: POKE 781,3: POKE 782,240: POKE 783,9: POKE 784,202: POKE 785,208: POKE 786,245: POKE 787,174
10930 POKE 788,0: POKE 789,3: POKE 790,76: POKE 791,5: POKE 792,3: POKE 793,32: POKE 794,63: POKE 795,255: POKE 796,96
10940 PT = 768:DR = 769:TN = 770
20000 REM INTRODUCTION
20010 IA$ = CHR$(15) + CHR$(1): REM SWITCH TO PAGE 1
20020 IB$ = CHR$(15) + CHR$(2): REM SWITCH TO PAGE 2
20030 IC$ = CHR$(16): REM CLEAR PAGE & HOME CURSOR
20040 IE$ = CHR$(5): REM CLEAR TO END OF LINE
20050 IP$ = CHR$(15) + CHR$(16): REM NORMAL PRINTING
20060 IT$ = CHR$(15) + CHR$(20): REM TRANSPARENT OVERLAY
20070 IV$ = CHR$(22): REM UPPER LEFT CORNER OF WINDOW
20080 IW$ = CHR$(23): REM LOWER RIGHT CORNER OF WINDOW
20090 IY$ = CHR$(25): REM FULL SCREEN WINDOW
20100 PRINT IB$;IC$;IP$;"HI! WELCOME TO..."
20110 VTAB 10: PRINT "DO YOU KNOW HOW TO PLAY THIS GAME?"
20120 PRINT IA$;IT$;: VTAB 1: HTAB 1: PRINT " ";
20200 FY = 1: FOR FX = 2 TO 32 STEP 2
20210 VTAB FY: HTAB FX: PRINT FROG$(1,3): FOR I = 1 TO 20: NEXT
20220 VTAB FY: HTAB FX +1: PRINT FROG$(1,4): FOR I = 1 TO 20: NEXT
20230 VTAB FY: HTAB FX +2: PRINT FROG$(1,1)
20240 FOR I = 1 TO 100: NEXT : NEXT
20250 FOR I = 1 TO 1000: NEXT : VTAB FY: HTAB FX: PRINT IP$;FROG$(0,1)
20260 FOR I = 1 TO 1000: NEXT :FD = 0: GOSUB 1100
20270 FOR I = 1 TO 2000: NEXT
20300 PRINT IT$;:BY = 9: FOR BX = 1 TO 37
20310 VTAB BY: HTAB BX: PRINT BUG$(0,1): FOR I = 1 TO 50: NEXT
20320 VTAB BY: HTAB BX: PRINT BUG$(0,2): FOR I = 1 TO 50: NEXT : NEXT
20330 VTAB BY: HTAB BX -1: PRINT BUG$(0,0)
20340 VTAB 10: HTAB 36:BY = 0
20350 GET A$: IF A$ = "Y" THEN BY = 1: VTAB 10: HTAB 36: PRINT "YES";
20360 IF A$ = "N" THEN BY = 0: VTAB 10: HTAB 36: PRINT IE$;"NO";
20370 IF A$ = CHR$(8) OR A$ = CHR$(24) THEN BY = 0: VTAB 10: HTAB 36: PRINT IE$;
20380 IF A$ < > CHR$(13) THEN 20350
20390 PRINT IP$;: GOSUB 1100: IF BY THEN VTAB 13: HTAB 1: PRINT "GOOD! LET'S BEGIN!"
20400 PRINT IT$;: FOR I = 1 TO 500: NEXT I
20410 FX = FX -1: VTAB FY: HTAB FX: PRINT FROG$(0,3);
20420 I = FY: FOR FY = I TO 18
20430 FX = FX -1: VTAB FY: HTAB FX: PRINT FROG$(0,4);
20440 NEXT : VTAB FY: HTAB FX: PRINT FROG$(0,1);
20450 FOR I = 1 TO 500: NEXT
20460 VTAB FY: HTAB FX: PRINT FROG$(1,1);
20470 FOR I = 1 TO 1000: NEXT
20480 PRINT IP$;:FD = 1: IF BY THEN GOSUB 1100: GOTO 20900
20500 VTAB 4: HTAB 1: PRINT IV$;: VTAB 18: HTAB 40: PRINT IW$;IC$;: SPEED= 60
20510 PRINT "WELL, IT'S REALLY NOT TOO DIFFICULT... ": PRINT
20520 PRINT "ALL YOU HAVE TO DO IS TO HELP THE FROG "
20530 PRINT "CATCH THE BUTTERFLY. YOU CAN TELL HIM "
20540 PRINT "WHICH WAY TO TURN AND HOW HIGH TO JUMP "
20550 PRINT "BY USING THE GAME PADDLES. IF YOU HIT "
20560 PRINT "THE BUTTON AT JUST THE RIGHT TIME, THE "
20570 PRINT "FROG WILL CATCH THE BUTTERFLY, AND YOU "
20580 PRINT "WILL BE AWARDED ONE FREE LUNCH!": PRINT
20590 PRINT "READY? HERE WE GO...";IY$;: SPEED= 255: GOSUB 1100
20900 VTAB 20: PRINT : PRINT D$;"BLOAD LILY PAD.PIC,A$4000"
20910 PRINT IA$;IT$;IC$;
20920 BX = 1:BY = 1
20990 GOTO 20
30000 PRINT "ERROR IN RLOAD OR RBOOT"
30010 POKE 216,0
30020 STOP

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/SKY3.SET.txt:

Offset Hex Data Characters
======= ================================================ =================
$000000 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000010 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000020 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000030 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000040 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000050 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000060 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000070 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000080 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000090 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000A0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000B0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000C0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000D0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000E0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0000F0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000100 00 00 00 00 00 00 00 00 00 00 00 00 20 14 0C 1F ........ .... ...
$000110 00 00 00 00 00 00 00 00 04 04 00 00 00 00 00 00 ........ ........
$000120 00 00 00 00 00 00 00 00 00 00 00 00 40 28 18 3E ........ ....@(.>
$000130 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000140 08 08 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000150 00 00 00 00 00 00 00 00 00 00 00 00 00 50 30 7C ........ .....P0|
$000160 00 00 00 00 01 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000170 10 10 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000180 00 00 00 00 00 00 00 00 00 00 00 00 00 20 60 78 ........ ..... `x
$000190 00 00 00 00 02 01 00 01 00 00 00 00 00 00 00 00 ........ ........
$0001A0 20 20 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ...... ........
$0001B0 00 00 00 00 00 00 00 00 00 00 00 00 00 40 40 70 ........ .....@@p
$0001C0 00 00 00 00 04 02 01 03 00 00 00 00 00 00 00 00 ........ ........
$0001D0 40 40 00 00 00 00 00 00 00 00 00 00 00 00 00 00 @@...... ........
$0001E0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0001F0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000200 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000210 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 60 ........ .......`
$000220 00 00 00 00 08 05 03 07 00 00 00 00 00 00 00 00 ........ ........
$000230 00 00 00 00 00 00 00 00 01 01 00 00 00 00 00 00 ........ ........
$000240 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 40 ........ .......@
$000250 00 00 00 00 10 0A 06 0F 00 00 00 00 00 00 00 00 ........ ........
$000260 00 00 00 00 00 00 00 00 02 02 00 00 00 00 00 00 ........ ........
$000270 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000280 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$000290 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0002A0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0002B0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0002C0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0002D0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0002E0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
$0002F0 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 ........ ........
** END **

Text found in DOS_Tool_Kit_v1.0_1980_Apple.do/SKYLAB.bas:

5 GOSUB 1000: REM PRINT TITLE
10 GOSUB 2000: REM LOAD FILES
20 GOSUB 3000: REM INITIALIZE CONSTANTS
30 GOSUB 4000: REM INITIALIZE SHIPS & EXPLOSIONS
40 GOSUB 5000: REM INITIALIZE CHAR GEN
45 PRINT P$;
50 VTAB RND(1) *20 +1: HTAB RND(1) *35 +1
60 PRINT A$;"1": REM SET CHARACTER SET TO LARGE SHIP
70 GOSUB 6000: REM FLY SHIP
80 IF PEEK( -16287) <128 THEN 70: REM CHECK BUTTON
90 GOSUB 7000: REM CRASH SHIP
100 GET KB$: IF KB$ < >C$ THEN 45
110 PRINT Z$: REM SET PARAMS TO DEFAULT
120 STOP
1000 REM
1010 REM PRINT TITLE
1020 REM
1030 TEXT : HOME : VTAB 13: HTAB 11
1040 PRINT "WELCOME BACK, SKYLAB!"
1050 PRINT : PRINT : PRINT
1060 PRINT "PADDLE 0 CONTROLS HOW FAST SKYLAB"
1070 PRINT "WILL FALL. THE BUTTON WILL START"
1080 PRINT "IT FALLING."
1090 PRINT "AFTER IT LANDS, PRESS THE SPACE"
1100 PRINT "BAR TO START A NEW GAME."
1110 RETURN
2000 REM
2010 REM LOAD FILES
2020 REM
2030 ADRS = 0: ONERR GOTO 2180
2040 PRINT CHR$(4);"BLOAD RBOOT": CALL 520: REM LOAD RLOAD
2050 ADRS = USR(0),"HRCG"
2060 POKE 216,0: REM TURN OFF ON ERR
2070 IF ADRS < = 0 THEN ADRS = ADRS +65536: REM MAKE ADRS POSITIVE
2080 CS = ADRS -3072: HIMEM: CS: REM MAKE SPACE FOR CHARACTER SETS
2090 CH = INT(CS/256):CL = CS -CH *256: REM GET HIGH & LOW BYTES
2100 REM LOAD CHARACTER SETS
2110 PRINT CHR$(4);"BLOAD SKY1.SET,A";CS
2120 PRINT CHR$(4);"BLOAD SKY2.SET,A";CS +768
2130 PRINT CHR$(4);"BLOAD SKY3.SET,A";CS +1536
2140 PRINT CHR$(4);"BLOAD MUSH.SET,A";CS +2304
2150 REM LOAD BACKGROUND
2160 PRINT CHR$(4);"BLOAD WORLD MAP.PIC,A$4000"
2170 RETURN
2180 REM RBOOT OR RLOAD FAILED
2190 PRINT "ERROR IN RBOOT OR RLOAD"
2200 POKE 216,0
2210 STOP
3000 REM
3010 REM SET CONSTANTS
3020 REM
3030 TEXT : HOME : HGR
3040 S = -16336:V = 300
3050 REM SET STRINGS FOR CONTROL CHARACTERS
3060 A$ = CHR$(1):B$ = CHR$(2):C$ = CHR$(3)
3070 D$ = CHR$(4):L$ = CHR$(12):O$ = CHR$(15)
3080 P$ = CHR$(16):Q$ = CHR$(17):T$ = CHR$(20)
3090 W$ = CHR$(23):Z$ = CHR$(26)
3100 RETURN
4000 REM
4010 REM INITIALIZE SKYLAB STRINGS
4020 REM
4030 S$(1) = B$ +"EFG" +C$ +"HIJ" +Q$ +D$
4040 S$(2) = B$ +"KLM" +C$ +"NOP" +Q$ +D$
4050 S$(3) = B$ +"QRS" +C$ +"TUV" +Q$ +D$
4060 S$(4) = B$ +"WXY" +C$ +"Z" +L$ +"AB" +Q$ +D$
4070 S$(5) = B$ +L$ +"CDE" +C$ +"FGH" +Q$ +D$
4080 S$(6) = B$ +L$ +"IJK" +C$ +"LMN" +Q$ +D$
4090 S$(7) = B$ +" AB" +C$ +" CD" +Q$ +D$
4100 REM EXPLOSION STRINGS
4110 E1$ = B$ +A$ +"4ABC" +C$ +"DEF" +Q$ +D$
4120 E2$ = B$ +A$ +"4GHI" +C$ +"KJL" +Q$ +D$
4130 E3$ = B$ +A$ +"4MNO" +C$ +"PQR" +Q$ +D$
4140 E4$ = B$ +A$ +"4STU" +C$ +"VWX" +Q$ +D$
4150 RETURN
5000 REM
5010 REM INITIALIZE HI-RES CHARACTER GENERATOR
5020 REM
5030 POKE ADRS +7,CL: POKE ADRS +8,CH: CALL ADRS +3: REM INIT HRP
5040 PRINT Z$: REM SET PARAMS TO DEFAULT
5050 PRINT O$;T$: REM TRANSPARENT MODE
5060 PRINT O$;W$;: REM WRAP SCREEN
5070 PRINT P$: REM CLEAR PAGE TO GET BACKGROUND
5080 RETURN
6000 REM
6010 REM FLY THE SHIP
6020 REM
6030 PRINT S$(1);
6040 A = PEEK(S) + PEEK(S) + PEEK(S) + PEEK(S) + PEEK(S)
6050 FOR I = 2 TO 7: PRINT S$(I);: NEXT : PRINT " ";
6060 RETURN
7000 REM
7010 REM CRASH THE SHIP
7020 REM
7030 A = INT( PDL(0)/5) +10
7040 V = 300
7050 FOR C = 0 TO 7: PRINT S$(C);:D = PEEK(S): NEXT : PRINT " ";
7060 IF V <200 THEN PRINT A$;"2";:V = V -300/A
7070 IF V <100 THEN PRINT A$;"3";:V = V -300/A
7080 V = V -300/A
7100 IF V >0 THEN 7050
7110 PRINT E1$;: FOR I = 1 TO 200: NEXT I
7120 PRINT E2$;: FOR I = 1 TO 200: NEXT I
7130 PRINT E3$;: FOR I = 1 TO 200: NEXT I
7140 PRINT E4$: FOR I = 1 TO 200: NEXT I
7150 RETURN